租用额外仓库

改变额外仓库的租用时间

StorageTimeChange 仓库ID 控制符时间

命令参数

参数	含义
仓库ID	仓库ID（1或2）
控制符	控制符（+、-、=）
时间	租用时间（单位：天）

命令说明

本命令用于改变额外仓库的租用时间

变量	作用说明
<$STORAGE2STATE>	额外仓库二状态（未开启、到期时间）
<$STORAGE3STATE>	额外仓库三状态（未开启、到期时间）
<$STORAGE4STATE>	额外仓库四状态【暂未启用】
<$STORAGE5STATE>	额外仓库五状态【暂未启用】

使用示例

[@main]
#ACT
StorageTimeChange 1 + 30
SendMsg 5 你的额外仓库一使用时间增加了30天
Break

相关文件例子

(@Storage @Getback)
%100
[@main]
{<$SELFNAME>=FCO=243}：\
　需要帮忙吗？目前不收保管费。\ \
<&打开仓库/@Storage>\
<&修改仓库密码/@StoragePass>\
<&租用仓库/@仓库_租用仓库>\
<&金融业务/@仓库_金融业务>\
<&关闭/@exit>\

[@仓库_租用仓库]
{<$SELFNAME>=FCO=243}：\
　您是不是觉得仓库容量不够用呢？我们\
现在推出{买一送一=FCO=251}活动，只要您租用一个\
仓库，我们将再加送您一个仓库。\
　价格：{100=FCO=251}元宝/{30=FCO=251}天 (可重复购买)\ \
　您当前额外仓库到期时间为：\
　仓库二：{<$STORAGE2STATE>=FCO=250}\
　仓库三：{<$STORAGE3STATE>=FCO=250}\ \
<&租用额外仓库/@仓库_租用仓库_租用>\
<&返回/@系统_交易NPC头_返回>\

[@仓库_租用仓库_租用]
#IF
CheckGameGold ? 100
#ACT
GameGold - 100
StorageTimeChange 2 + 30
StorageTimeChange 3 + 30
MessageBox 恭喜您，成功的为额外仓库增加了30天时间
Goto @仓库_租用仓库
Break
#ELSEACT
MessageBox 对不起，您的元宝不够支付本次费用！
Break

[@仓库_金融业务]
{<$SELFNAME>=FCO=243}：\
　在这里我可以帮你将金币转换为金条，\
将金条转换为金砖，请问您需要什么业务？\ \
　100W金币 = 1根金条\
　5根金条 = 1块金砖\ \
<&对换金条/@仓库_金融业务_对换金条>\
<&对换金砖/@仓库_金融业务_对换金砖>\
<&返回/@系统_交易NPC头_返回>\

[@仓库_金融业务_对换金条]
#IF
CheckGold 1000000
#ACT
Take 金币 1000000
Give 金条 1
MessageBox 对换成功！
Break
#ELSEACT
MessageBox 对不起，您的金币不够啊！
Break

[@仓库_金融业务_对换金砖]
#IF
CheckItemCount 金条 ? 5
#ACT
TakeCount 金条 5
Give 金砖 1
MessageBox 对换成功！
Break
#ELSEACT
MessageBox 对不起，您的金条不够啊！
Break